Modularize gdbinit

.gdb/breakpoints.gdb

@@ -0,0 +1,121 @@
+define bpl
+  info breakpoints
+end
+document bpl
+List all breakpoints.
+end
+
+
+define bp
+  if $argc != 1
+    help bp
+  else
+    break $arg0
+  end
+end
+document bp
+Set breakpoint.
+Usage: bp LOCATION
+LOCATION may be a line number, function name, or "*" and an address.
+To break on a symbol you must enclose symbol name inside "".
+Example:
+bp "[NSControl stringValue]"
+Or else you can use directly the break command (break [NSControl stringValue])
+end
+
+
+define bpc
+  if $argc != 1
+    help bpc
+  else
+    clear $arg0
+  end
+end
+document bpc
+Clear breakpoint.
+Usage: bpc LOCATION
+LOCATION may be a line number, function name, or "*" and an address.
+end
+
+
+define bpe
+  if $argc != 1
+    help bpe
+  else
+    enable $arg0
+  end
+end
+document bpe
+Enable breakpoint with number NUM.
+Usage: bpe NUM
+end
+
+
+define bpd
+  if $argc != 1
+    help bpd
+  else
+    disable $arg0
+  end
+end
+document bpd
+Disable breakpoint with number NUM.
+Usage: bpd NUM
+end
+
+
+define bpt
+  if $argc != 1
+    help bpt
+  else
+    tbreak $arg0
+  end
+end
+document bpt
+Set a temporary breakpoint.
+This breakpoint will be automatically deleted when hit!.
+Usage: bpt LOCATION
+LOCATION may be a line number, function name, or "*" and an address.
+end
+
+
+define bpm
+  if $argc != 1
+    help bpm
+  else
+    awatch $arg0
+  end
+end
+document bpm
+Set a read/write breakpoint on EXPRESSION, e.g. *address.
+Usage: bpm EXPRESSION
+end
+
+
+define bhb
+  if $argc != 1
+    help bhb
+  else
+    hb $arg0
+  end
+end
+document bhb
+Set hardware assisted breakpoint.
+Usage: bhb LOCATION
+LOCATION may be a line number, function name, or "*" and an address.
+end
+
+
+define bht
+  if $argc != 1
+    help bht
+  else
+    thbreak $arg0
+  end
+end
+document bht
+Set a temporary hardware breakpoint.
+This breakpoint will be automatically deleted when hit!
+Usage: bht LOCATION
+LOCATION may be a line number, function name, or "*" and an address.
+end

.gdb/carbon.gdb

@@ -0,0 +1,49 @@
+define print-char
+	if ($arg0 > 0xff)
+		print "not a character"
+		""
+	else
+		if ($arg0 == '\n')
+			printf "\\n"
+		else
+			if ($arg0 == '\t')
+				printf "\\t"
+			else
+				if ($arg0 == '\r')
+					printf "\\r"
+				else
+					if ($arg0 == '\'')
+						printf "\\'"
+					else
+						if (($arg0 < 0x20) || ($arg0 >= 0x7f))
+							printf "\\%03o", $arg0
+						else
+							printf "%c", $arg0
+						end
+					end
+				end
+			end
+		end
+	end
+end
+document print-char
+Print a single character in a readable fashion.
+end
+
+define print-ostype
+	set $tmp0 = ($arg0)
+	printf "'"
+	set $tmp1 = (($tmp0 & 0xff000000) >> 24)
+	print-char $tmp1
+	set $tmp1 = (($tmp0 & 0x00ff0000) >> 16)
+	print-char $tmp1
+	set $tmp1 = (($tmp0 & 0x0000ff00) >> 8)
+	print-char $tmp1
+	set $tmp1 = (($tmp0 & 0x000000ff) >> 0)
+	print-char $tmp1
+	printf "'"
+	printf "\n"
+end
+document print-ostype
+Print a value as an OSType (four-byte character string).
+end