Add Nix support

README.md

@@ -36,6 +36,35 @@ Or from a checkout: `docker compose up -d` (see `docker-compose.yml`).
 2. Attach a **volume** mounted at `/data`.
 3. That's it — the server listens on Railway's `PORT` automatically.
 
+### NixOS
+Add this repository as a flake input and add the module to your configuration:
+```nix
+{
+    crosspoint-sync.url = "github:rogierknoester/crosspoint-sync";
+    crosspoint-sync.inputs.nixpkgs.follows = "nixpkgs";
+    ...
+}: {
+  nixosConfigurations = {
+    myServer = nixpkgs.lib.nixosSystem {
+      ...
+      modules = [
+        ./configuration.nix
+        crosspoint-sync.nixosModules.crosspoint-sync
+      ];
+    };
+  };
+}
+```
+
+Now you can enable it in your `configuration.nix`:
+```nix
+services.crosspoint-sync = {
+  enable = true;
+  port = 8080;
+  registration = true;
+};
+```
+
 ### Bare Node (≥ 22.13)
 
 ```sh

flake.nix

@@ -0,0 +1,33 @@
+{
+  description = "crosspoint-sync flake";
+
+  inputs = {
+    nixpkgs.url = "github:nixos/nixpkgs/nixpkgs-unstable";
+    flake-utils.url = "github:numtide/flake-utils";
+  };
+
+  outputs =
+    {
+      nixpkgs,
+      flake-utils,
+      ...
+    }:
+    {
+      nixosModules = {
+        crosspoint-sync = import ./nix/module.nix;
+      };
+    }
+    // flake-utils.lib.eachDefaultSystem (
+      system:
+      let
+        pkgs = import nixpkgs { inherit system; };
+        crosspoint-sync = pkgs.callPackage ./nix/package.nix { };
+      in
+      {
+        packages = {
+          inherit crosspoint-sync;
+          default = crosspoint-sync;
+        };
+      }
+    );
+}

nix/module.nix

@@ -0,0 +1,120 @@
+{
+  pkgs,
+  lib,
+  config,
+  ...
+}:
+
+let
+
+  cfg = config.services.crosspoint-sync;
+  crosspoint-sync = pkgs.callPackage ./package.nix { };
+in
+with lib;
+{
+
+  options.services.crosspoint-sync = {
+    enable = mkEnableOption "Enable crosspoint-sync server";
+
+    port = mkOption {
+      type = types.int;
+      description = "Port to run crosspoint-sync server on";
+      default = 8080;
+    };
+
+    dataDir = mkOption {
+      type = types.str;
+      description = "Path to the folder containing all data";
+      default = "/var/lib/crosspoint-sync";
+    };
+
+    databaseFile = mkOption {
+      type = types.str;
+      description = "Filename of the SQLite database in, in the dataDir";
+      default = "crosspoint.db";
+    };
+
+    registration = mkOption {
+      type = types.bool;
+      description = "Have registration enabled or not";
+      default = true;
+    };
+
+    tokenEncryptionKeyFile = mkOption {
+      type = types.nullOr types.str;
+      description = "Path to the secret that contains the encryption key";
+    };
+
+    authRateLimit = mkOption {
+      type = types.int;
+      description = "Per-IP limit on registrations";
+      default = 30;
+    };
+
+    user = mkOption {
+      type = types.str;
+      description = "User to run crosspoint-sync with";
+      default = "crosspoint-sync";
+    };
+
+    group = mkOption {
+      type = types.str;
+      description = "Group to run crosspoint-sync with";
+      default = "crosspoint-sync";
+    };
+
+  };
+
+  config = mkIf cfg.enable {
+    systemd.services.crosspoint-sync = {
+      description = "crosspoint-sync server";
+      wantedBy = [ "multi-user.target" ];
+
+      serviceConfig = {
+        Type = "simple";
+        ExecStart =
+          if (cfg.tokenEncryptionKeyFile != null) then
+            pkgs.writeShellScript "crosspoint-sync-credential-loader" ''
+              export TOKEN_ENC_KEY = $(cat ${cfg.tokenEncryptionKeyFile})
+              exec ${lib.getExe crosspoint-sync}
+            ''
+          else
+            "${lib.getExe crosspoint-sync}";
+        Restart = "on-failure";
+
+        User = cfg.user;
+        Group = cfg.group;
+
+        ReadWritePaths = [ cfg.dataDir ];
+        StateDirectory = mkIf (cfg.dataDir == "/var/lib/crosspoint-sync") "crosspoint-sync";
+        ProtectSystem = "strict";
+        ProtectHome = true;
+        NoNewPrivileges = true;
+        PrivateDevices = true;
+        AmbientCapabilities = mkIf (cfg.port <= 1024) [ "CAP_NET_BIND_SERVICE" ];
+      };
+
+      environment = {
+        PORT = builtins.toString cfg.port;
+        DATABASE_PATH = builtins.toString (lib.path.append (/. + cfg.dataDir) cfg.databaseFile);
+        REGISTRATION_DISABLED = if !cfg.registration then "true" else "false";
+        AUTH_RATE_LIMIT_PER_MINUTE = builtins.toString cfg.authRateLimit;
+      };
+
+    };
+
+    networking.firewall.allowedTCPPorts = [ cfg.port ];
+
+    users = {
+      users.crosspoint-sync = mkIf (cfg.user == "crosspoint-sync") {
+        description = "crosspoint-sync service user";
+        isSystemUser = true;
+        group = cfg.group;
+      };
+
+      groups.crosspoint-sync = mkIf (cfg.group == "crosspoint-sync") { };
+    };
+
+  };
+
+}

nix/package.nix

@@ -0,0 +1,35 @@
+{ pkgs, lib }:
+
+with pkgs;
+buildNpmPackage {
+  pname = "crosspoint-sync";
+  version = "git";
+  src = ../.;
+
+  npmDeps = importNpmLock {
+    npmRoot = ../.;
+  };
+
+  npmConfigHook = importNpmLock.npmConfigHook;
+
+  buildPhase = ''
+    npm run build
+  '';
+
+  installPhase = ''
+    runHook preInstall
+    mkdir -p $out/lib $out/bin
+    cp -r package.json dist node_modules assets migrations $out/lib/
+    makeWrapper ${lib.getExe nodejs} $out/bin/crosspoint-sync \
+      --add-flags "$out/lib/dist/index.js"
+    runHook postInstall
+  '';
+
+  nativeBuildInputs = [ pkgs.makeWrapper ];
+
+  meta = {
+    description = "Lightweight KoSync Server for Syncing Crosspoint/CrossInk stats & progress";
+    homepage = "https://github.com/crosspoint-reader/crosspoint-sync";
+    mainProgram = "crosspoint-sync";
+  };
+}

result

@@ -0,0 +1 @@
+/nix/store/5hycgszh612nxnbjbb0lbgaws9ay8l8g-crosspoint-sync-git