feat: Add V4 Addresses Provider

src/addresses-provider/V4AddressesProvider.sol

@@ -0,0 +1,166 @@
+// SPDX-License-Identifier: LicenseRef-BUSL
+pragma solidity 0.8.28;
+
+import {Ownable2StepUpgradeable} from 'src/dependencies/openzeppelin-upgradeable/Ownable2StepUpgradeable.sol';
+import {EnumerableSet} from 'src/dependencies/openzeppelin/EnumerableSet.sol';
+import {V4AddressesProviderStorage} from 'src/addresses-provider/V4AddressesProviderStorage.sol';
+import {IV4AddressesProvider} from 'src/addresses-provider/interfaces/IV4AddressesProvider.sol';
+
+/// @title V4AddressesProvider
+/// @author Aave Labs
+/// @notice Main registry of Aave V4 contract addresses.
+abstract contract V4AddressesProvider is
+  V4AddressesProviderStorage,
+  Ownable2StepUpgradeable,
+  IV4AddressesProvider
+{
+  using EnumerableSet for *;
+
+  /// @inheritdoc IV4AddressesProvider
+  string public constant CANONICAL_HUB_TAG = 'CANONICAL_HUB';
+
+  /// @inheritdoc IV4AddressesProvider
+  string public constant CANONICAL_SPOKE_TAG = 'CANONICAL_SPOKE';
+
+  /// @inheritdoc IV4AddressesProvider
+  string public constant TOKENIZATION_SPOKE_TAG = 'TOKENIZATION_SPOKE';
+
+  /// @inheritdoc IV4AddressesProvider
+  string public constant TREASURY_SPOKE_TAG = 'TREASURY_SPOKE';
+
+  /// @dev To be overridden by the inheriting V4AddressesProvider instance contract.
+  function initialize(address owner) external virtual;
+
+  /// @inheritdoc IV4AddressesProvider
+  function setAddress(
+    string memory name,
+    string memory tag,
+    address newAddress
+  ) external onlyOwner {
+    _setAddress({name: name, tag: tag, newAddress: newAddress});
+  }
+
+  /// @inheritdoc IV4AddressesProvider
+  function setCanonicalHub(string memory name, address hub) external onlyOwner {
+    _setAddress({name: name, tag: CANONICAL_HUB_TAG, newAddress: hub});
+  }
+
+  /// @inheritdoc IV4AddressesProvider
+  function setCanonicalSpoke(string memory name, address spoke) external onlyOwner {
+    _setAddress({name: name, tag: CANONICAL_SPOKE_TAG, newAddress: spoke});
+  }
+
+  /// @inheritdoc IV4AddressesProvider
+  function setTokenizationSpoke(string memory name, address spoke) external onlyOwner {
+    _setAddress({name: name, tag: TOKENIZATION_SPOKE_TAG, newAddress: spoke});
+  }
+
+  /// @inheritdoc IV4AddressesProvider
+  function setTreasurySpoke(string memory name, address spoke) external onlyOwner {
+    _setAddress({name: name, tag: TREASURY_SPOKE_TAG, newAddress: spoke});
+  }
+
+  /// @inheritdoc IV4AddressesProvider
+  function getAddressEntry(bytes32 id) external view returns (AddressEntry memory) {
+    return _addressEntries[id];
+  }
+
+  /// @inheritdoc IV4AddressesProvider
+  function getIds(string memory tag) external view returns (bytes32[] memory) {
+    return _taggedIds[tag].values();
+  }
+
+  /// @inheritdoc IV4AddressesProvider
+  function getTags() external view returns (string[] memory) {
+    return _tags.values();
+  }
+
+  /// @inheritdoc IV4AddressesProvider
+  function getCanonicalHub(string memory name) external view returns (address) {
+    return getAddress({name: name, tag: CANONICAL_HUB_TAG});
+  }
+
+  /// @inheritdoc IV4AddressesProvider
+  function getCanonicalHubs() external view returns (address[] memory) {
+    return getAddresses(CANONICAL_HUB_TAG);
+  }
+
+  /// @inheritdoc IV4AddressesProvider
+  function getCanonicalSpoke(string memory name) external view returns (address) {
+    return getAddress({name: name, tag: CANONICAL_SPOKE_TAG});
+  }
+
+  /// @inheritdoc IV4AddressesProvider
+  function getCanonicalSpokes() external view returns (address[] memory) {
+    return getAddresses(CANONICAL_SPOKE_TAG);
+  }
+
+  /// @inheritdoc IV4AddressesProvider
+  function getTokenizationSpoke(string memory name) external view returns (address) {
+    return getAddress({name: name, tag: TOKENIZATION_SPOKE_TAG});
+  }
+
+  /// @inheritdoc IV4AddressesProvider
+  function getTokenizationSpokes() external view returns (address[] memory) {
+    return getAddresses(TOKENIZATION_SPOKE_TAG);
+  }
+
+  /// @inheritdoc IV4AddressesProvider
+  function getTreasurySpoke(string memory name) external view returns (address) {
+    return getAddress({name: name, tag: TREASURY_SPOKE_TAG});
+  }
+
+  /// @inheritdoc IV4AddressesProvider
+  function getTreasurySpokes() external view returns (address[] memory) {
+    return getAddresses(TREASURY_SPOKE_TAG);
+  }
+
+  /// @inheritdoc IV4AddressesProvider
+  function getAddress(bytes32 id) public view returns (address) {
+    return _addressEntries[id].addr;
+  }
+
+  /// @inheritdoc IV4AddressesProvider
+  function getAddress(string memory name, string memory tag) public view returns (address) {
+    return getAddress(getId({name: name, tag: tag}));
+  }
+
+  /// @inheritdoc IV4AddressesProvider
+  function getAddresses(string memory tag) public view returns (address[] memory) {
+    bytes32[] memory ids = _taggedIds[tag].values();
+    address[] memory addresses = new address[](ids.length);
+    for (uint256 i = 0; i < ids.length; i++) {
+      addresses[i] = _addressEntries[ids[i]].addr;
+    }
+    return addresses;
+  }
+
+  /// @inheritdoc IV4AddressesProvider
+  function getId(string memory name, string memory tag) public pure returns (bytes32) {
+    return keccak256(bytes(string.concat(name, '_', tag)));
+  }
+
+  function _setAddress(string memory name, string memory tag, address newAddress) internal {
+    require(bytes(name).length > 0, InvalidName());
+    require(bytes(tag).length > 0, InvalidTag());
+
+    bytes32 id = getId({name: name, tag: tag});
+    AddressEntry memory oldEntry = _addressEntries[id];
+
+    if (newAddress == address(0)) {
+      require(oldEntry.addr != address(0), AddressNotSet(id));
+      _taggedIds[oldEntry.tag].remove(id);
+      if (_taggedIds[oldEntry.tag].length() == 0) {
+        _tags.remove(oldEntry.tag);
+      }
+      delete _addressEntries[id];
+    } else {
+      require(oldEntry.addr == address(0), AddressAlreadySet(id));
+      _addressEntries[id] = AddressEntry({addr: newAddress, tag: tag});
+      _taggedIds[tag].add(id);
+      _tags.add(tag);
+    }
+
+    emit AddressSet(id, name, tag, oldEntry.addr, newAddress);
+  }
+}

src/addresses-provider/V4AddressesProviderStorage.sol

@@ -0,0 +1,23 @@
+// SPDX-License-Identifier: LicenseRef-BUSL
+pragma solidity 0.8.28;
+
+import {EnumerableSet} from 'src/dependencies/openzeppelin/EnumerableSet.sol';
+import {IV4AddressesProvider} from 'src/addresses-provider/interfaces/IV4AddressesProvider.sol';
+
+/// @title V4AddressesProviderStorage
+/// @author Aave Labs
+/// @notice Storage layout for the V4AddressesProvider contract.
+/// @dev This contract defines all storage variables used by the V4AddressesProvider.
+abstract contract V4AddressesProviderStorage {
+  /// @dev Map of entry identifiers to address entries.
+  mapping(bytes32 id => IV4AddressesProvider.AddressEntry) internal _addressEntries;
+
+  /// @dev Map of tags to set of entry identifiers.
+  mapping(string tag => EnumerableSet.Bytes32Set ids) internal _taggedIds;
+
+  /// @dev Set of all tags with at least one registered entry.
+  EnumerableSet.StringSet internal _tags;
+
+  /// @dev Reserved storage space to allow for future layout updates.
+  uint256[50] private __gap;
+}

src/addresses-provider/instances/V4AddressesProviderInstance.sol

@@ -0,0 +1,23 @@
+// SPDX-License-Identifier: LicenseRef-BUSL
+pragma solidity 0.8.28;
+
+import {V4AddressesProvider} from 'src/addresses-provider/V4AddressesProvider.sol';
+
+/// @title V4AddressesProviderInstance
+/// @author Aave Labs
+/// @notice Implementation contract for the V4AddressesProvider.
+contract V4AddressesProviderInstance is V4AddressesProvider {
+  uint64 public constant ADDRESSES_PROVIDER_REVISION = 1;
+
+  /// @dev Constructor.
+  constructor() {
+    _disableInitializers();
+  }
+
+  /// @notice Initializer.
+  /// @param owner The address of the owner.
+  function initialize(address owner) external override reinitializer(ADDRESSES_PROVIDER_REVISION) {
+    __Ownable_init(owner);
+    __Ownable2Step_init();
+  }
+}

src/addresses-provider/interfaces/IV4AddressesProvider.sol

@@ -0,0 +1,162 @@
+// SPDX-License-Identifier: LicenseRef-BUSL
+pragma solidity ^0.8.0;
+
+/// @title IV4AddressesProvider
+/// @author Aave Labs
+/// @notice Main registry of the Hub and Spoke addresses of an Aave V4 instance.
+interface IV4AddressesProvider {
+  /// @notice Address entry registered under an identifier.
+  /// @param addr The registered address.
+  /// @param tag The tag grouping the entry.
+  struct AddressEntry {
+    address addr;
+    string tag;
+  }
+
+  /// @notice Emitted when the address associated with a name and tag is updated.
+  /// @param id The identifier of the entry.
+  /// @param name The name of the entry.
+  /// @param tag The tag grouping the entry.
+  /// @param oldAddress The previous address of the entry.
+  /// @param newAddress The new address of the entry.
+  event AddressSet(
+    bytes32 indexed id,
+    string name,
+    string tag,
+    address indexed oldAddress,
+    address indexed newAddress
+  );
+
+  /// @notice Thrown when an empty tag is supplied.
+  error InvalidTag();
+
+  /// @notice Thrown when an empty name is supplied.
+  error InvalidName();
+
+  /// @notice Thrown when an address is already registered under the identifier.
+  error AddressAlreadySet(bytes32 id);
+
+  /// @notice Thrown when no address is registered under the identifier.
+  error AddressNotSet(bytes32 id);
+
+  /// @notice Returns the tag grouping all canonical Hubs.
+  function CANONICAL_HUB_TAG() external view returns (string memory);
+
+  /// @notice Returns the tag grouping all canonical Spokes.
+  function CANONICAL_SPOKE_TAG() external view returns (string memory);
+
+  /// @notice Returns the tag grouping all tokenization Spokes.
+  function TOKENIZATION_SPOKE_TAG() external view returns (string memory);
+
+  /// @notice Returns the tag grouping all treasury Spokes.
+  function TREASURY_SPOKE_TAG() external view returns (string memory);
+
+  /// @notice Associates an address with a name, grouped under a tag.
+  /// @dev Associating the zero address removes the entry and its identifier from enumeration, it reverts if no address is registered.
+  /// @dev Reverts if an address is already registered under the identifier, it must be removed first.
+  /// @param name The name of the entry.
+  /// @param tag The tag grouping the entry.
+  /// @param newAddress The address to associate with the name and tag.
+  function setAddress(string memory name, string memory tag, address newAddress) external;
+
+  /// @notice Registers the canonical Hub associated with a name.
+  /// @dev Registering the zero address removes the entry and its identifier from enumeration, it reverts if no address is registered.
+  /// @dev Reverts if an address is already registered under the identifier, it must be removed first.
+  /// @param name The name of the Hub.
+  /// @param hub The address of the Hub.
+  function setCanonicalHub(string memory name, address hub) external;
+
+  /// @notice Registers the canonical Spoke associated with a name.
+  /// @dev Registering the zero address removes the entry and its identifier from enumeration, it reverts if no address is registered.
+  /// @dev Reverts if an address is already registered under the identifier, it must be removed first.
+  /// @param name The name of the Spoke.
+  /// @param spoke The address of the Spoke.
+  function setCanonicalSpoke(string memory name, address spoke) external;
+
+  /// @notice Registers the tokenization Spoke associated with a name.
+  /// @dev Registering the zero address removes the entry and its identifier from enumeration, it reverts if no address is registered.
+  /// @dev Reverts if an address is already registered under the identifier, it must be removed first.
+  /// @param name The name of the Spoke.
+  /// @param spoke The address of the Spoke.
+  function setTokenizationSpoke(string memory name, address spoke) external;
+
+  /// @notice Registers the treasury Spoke associated with a name.
+  /// @dev Registering the zero address removes the entry and its identifier from enumeration, it reverts if no address is registered.
+  /// @dev Reverts if an address is already registered under the identifier, it must be removed first.
+  /// @param name The name of the Spoke.
+  /// @param spoke The address of the Spoke.
+  function setTreasurySpoke(string memory name, address spoke) external;
+
+  /// @notice Returns the address associated with an identifier.
+  /// @param id The identifier of the entry.
+  /// @return The address of the entry, the zero address if none is registered.
+  function getAddress(bytes32 id) external view returns (address);
+
+  /// @notice Returns the address associated with a name and tag.
+  /// @param name The name of the entry.
+  /// @param tag The tag grouping the entry.
+  /// @return The address of the entry, the zero address if none is registered.
+  function getAddress(string memory name, string memory tag) external view returns (address);
+
+  /// @notice Returns the address entry associated with an identifier.
+  /// @param id The identifier of the entry.
+  /// @return The address entry associated with the identifier.
+  function getAddressEntry(bytes32 id) external view returns (AddressEntry memory);
+
+  /// @notice Returns the identifiers of all entries grouped under a tag.
+  /// @param tag The tag grouping the entries.
+  /// @return The list of identifiers.
+  function getIds(string memory tag) external view returns (bytes32[] memory);
+
+  /// @notice Returns the addresses of all entries grouped under a tag.
+  /// @param tag The tag grouping the entries.
+  /// @return The list of addresses.
+  function getAddresses(string memory tag) external view returns (address[] memory);
+
+  /// @notice Returns all tags with at least one registered entry.
+  /// @return The list of tags.
+  function getTags() external view returns (string[] memory);
+
+  /// @notice Returns the canonical Hub associated with a name.
+  /// @param name The name of the Hub.
+  /// @return The address of the Hub, the zero address if none is registered.
+  function getCanonicalHub(string memory name) external view returns (address);
+
+  /// @notice Returns the addresses of all registered canonical Hubs.
+  /// @return The list of canonical Hub addresses.
+  function getCanonicalHubs() external view returns (address[] memory);
+
+  /// @notice Returns the canonical Spoke associated with a name.
+  /// @param name The name of the Spoke.
+  /// @return The address of the Spoke, the zero address if none is registered.
+  function getCanonicalSpoke(string memory name) external view returns (address);
+
+  /// @notice Returns the addresses of all registered canonical Spokes.
+  /// @return The list of canonical Spoke addresses.
+  function getCanonicalSpokes() external view returns (address[] memory);
+
+  /// @notice Returns the tokenization Spoke associated with a name.
+  /// @param name The name of the Spoke.
+  /// @return The address of the Spoke, the zero address if none is registered.
+  function getTokenizationSpoke(string memory name) external view returns (address);
+
+  /// @notice Returns the addresses of all registered tokenization Spokes.
+  /// @return The list of tokenization Spoke addresses.
+  function getTokenizationSpokes() external view returns (address[] memory);
+
+  /// @notice Returns the treasury Spoke associated with a name.
+  /// @param name The name of the Spoke.
+  /// @return The address of the Spoke, the zero address if none is registered.
+  function getTreasurySpoke(string memory name) external view returns (address);
+
+  /// @notice Returns the addresses of all registered treasury Spokes.
+  /// @return The list of treasury Spoke addresses.
+  function getTreasurySpokes() external view returns (address[] memory);
+
+  /// @notice Returns the identifier of the entry associated with a name and tag.
+  /// @dev The identifier is the hash of `<name>_<tag>` (e.g. `CORE_CANONICAL_HUB`).
+  /// @param name The name of the entry.
+  /// @param tag The tag grouping the entry.
+  /// @return The identifier of the entry.
+  function getId(string memory name, string memory tag) external pure returns (bytes32);
+}