Add OrvexCL PancakeInfinity fork to Robinhood

CHANGELOG.md

@@ -13,6 +13,8 @@
 * Fix a `metaTx` malleability bug in `CrossChainReceiverFactory`
   (contract is not deployed; no funds at risk) after a report in
   Immunefi bug 78645
+* Add Orvex CL PancakeInfinity fork to RobinHood chain
+  * Add `PANCAKE_INFINITY`, `PANCAKE_INFINITY_VIP`, and `METATXN_PANCAKE_INFINITY_VIP`
 
 ## 2026-07-27
 

src/chains/Base/Common.sol

@@ -10,7 +10,7 @@ import {UniswapV4} from "../../core/UniswapV4.sol";
 import {IPoolManager} from "../../core/UniswapV4Types.sol";
 import {EulerSwap, IEVC, IEulerSwap} from "../../core/EulerSwap.sol";
 import {BalancerV3} from "../../core/BalancerV3.sol";
-import {PancakeInfinity} from "../../core/PancakeInfinity.sol";
+import {PancakeInfinity} from "../../core/pancakeInfinityForks/PancakeInfinity.sol";
 import {Renegade, BASE_SELECTOR} from "../../core/Renegade.sol";
 import {Bebop} from "../../core/Bebop.sol";
 import {Hanji} from "../../core/Hanji.sol";

src/chains/Bnb/Common.sol

@@ -9,7 +9,7 @@ import {DodoV1, IDodoV1} from "../../core/DodoV1.sol";
 import {DodoV2, IDodoV2} from "../../core/DodoV2.sol";
 import {UniswapV4} from "../../core/UniswapV4.sol";
 import {IPoolManager} from "../../core/UniswapV4Types.sol";
-import {PancakeInfinity} from "../../core/PancakeInfinity.sol";
+import {PancakeInfinity} from "../../core/pancakeInfinityForks/PancakeInfinity.sol";
 import {EulerSwap, IEVC, IEulerSwap} from "../../core/EulerSwap.sol";
 import {Bebop} from "../../core/Bebop.sol";
 

src/chains/RobinHood/Common.sol

@@ -35,14 +35,15 @@ import {swapHoodV3Factory, swapHoodV3InitHash, swapHoodV3ForkId} from "../../cor
 import {gigaDexV3Factory, gigaDexV3InitHash, gigaDexV3ForkId} from "../../core/univ3forks/GigaDexV3.sol";
 import {IAlgebraCallback} from "../../core/univ3forks/Algebra.sol";
 import {ROBINHOOD_POOL_MANAGER} from "../../core/UniswapV4Addresses.sol";
+import {OrvexCL} from "../../core/pancakeInfinityForks/OrvexCL.sol";
 
 import {FastLogic} from "../../utils/FastLogic.sol";
 
 // Solidity inheritance is stupid
 import {SettlerSwapAbstract} from "../../SettlerAbstract.sol";
 import {Permit2PaymentAbstract} from "../../core/Permit2PaymentAbstract.sol";
 
-abstract contract RobinHoodMixin is FreeMemory, SettlerBase, UniswapV4, EkuboV3, Hanji {
+abstract contract RobinHoodMixin is FreeMemory, SettlerBase, UniswapV4, EkuboV3, Hanji, OrvexCL {
     using FastLogic for bool;
 
     constructor() {
@@ -59,7 +60,8 @@ abstract contract RobinHoodMixin is FreeMemory, SettlerBase, UniswapV4, EkuboV3,
         if (super._dispatch(i, action, data, slippage)) {
             return true;
         } else if ((action == uint32(ISettlerActions.UNISWAPV4.selector))
-            .or(action == uint32(ISettlerActions.EKUBOV3.selector))) {
+            .or(action == uint32(ISettlerActions.EKUBOV3.selector))
+            .or(action == uint32(ISettlerActions.PANCAKE_INFINITY.selector))) {
             (
                 address recipient,
                 IERC20 sellToken,
@@ -73,8 +75,10 @@ abstract contract RobinHoodMixin is FreeMemory, SettlerBase, UniswapV4, EkuboV3,
 
             if (action == uint32(ISettlerActions.UNISWAPV4.selector)) {
                 sellToUniswapV4(recipient, sellToken, bps, feeOnTransfer, hashMul, hashMod, fills, amountOutMin);
-            } else { // if (action == uint32(ISettlerActions.EKUBOV3.selector))
+            } else if (action == uint32(ISettlerActions.EKUBOV3.selector)) {
                 sellToEkuboV3(recipient, sellToken, bps, feeOnTransfer, hashMul, hashMod, fills, amountOutMin);
+            } else { // if (action == uint32(ISettlerActions.PANCAKE_INFINITY.selector))
+                sellToPancakeInfinity(recipient, sellToken, bps, feeOnTransfer, hashMul, hashMod, fills, amountOutMin);
             }
         } else if (action == uint32(ISettlerActions.HANJI.selector)) {
             (

src/chains/RobinHood/MetaTxn.sol

@@ -32,7 +32,8 @@ contract RobinHoodSettlerMetaTxn is SettlerMetaTxn, RobinHoodMixin {
         if (super._dispatchVIP(action, data, sig)) {
             return true;
         } else if ((action == uint32(ISettlerActions.METATXN_UNISWAPV4_VIP.selector))
-            .or(action == uint32(ISettlerActions.METATXN_EKUBOV3_VIP.selector))) {
+            .or(action == uint32(ISettlerActions.METATXN_EKUBOV3_VIP.selector))
+            .or(action == uint32(ISettlerActions.METATXN_PANCAKE_INFINITY_VIP.selector))) {
             (
                 address recipient,
                 ISignatureTransfer.PermitTransferFrom memory permit,
@@ -47,8 +48,10 @@ contract RobinHoodSettlerMetaTxn is SettlerMetaTxn, RobinHoodMixin {
 
             if (action == uint32(ISettlerActions.METATXN_UNISWAPV4_VIP.selector)) {
                 sellToUniswapV4VIP(recipient, feeOnTransfer, hashMul, hashMod, fills, permit, sig, amountOutMin);
-            } else { // if (action == uint32(ISettlerActions.METATXN_EKUBOV3_VIP.selector))
+            } else if (action == uint32(ISettlerActions.METATXN_EKUBOV3_VIP.selector)) {
                 sellToEkuboV3VIP(recipient, feeOnTransfer, hashMul, hashMod, fills, permit, sig, amountOutMin);
+            } else { // if (action == uint32(ISettlerActions.METATXN_PANCAKE_INFINITY_VIP.selector))
+                sellToPancakeInfinityVIP(recipient, feeOnTransfer, hashMul, hashMod, fills, permit, sig, amountOutMin);
             }
         } else {
             return false;

src/chains/RobinHood/TakerSubmitted.sol

@@ -25,7 +25,8 @@ contract RobinHoodSettler is Settler, RobinHoodMixin {
         if (super._dispatchVIP(action, data)) {
             return true;
         } else if ((action == uint32(ISettlerActions.UNISWAPV4_VIP.selector))
-            .or(action == uint32(ISettlerActions.EKUBOV3_VIP.selector))) {
+            .or(action == uint32(ISettlerActions.EKUBOV3_VIP.selector))
+            .or(action == uint32(ISettlerActions.PANCAKE_INFINITY_VIP.selector))) {
             (
                 address recipient,
                 ISignatureTransfer.PermitTransferFrom memory permit,
@@ -41,8 +42,10 @@ contract RobinHoodSettler is Settler, RobinHoodMixin {
 
             if (action == uint32(ISettlerActions.UNISWAPV4_VIP.selector)) {
                 sellToUniswapV4VIP(recipient, feeOnTransfer, hashMul, hashMod, fills, permit, sig, amountOutMin);
-            } else { // if (action == uint32(ISettlerActions.EKUBOV3_VIP.selector))
+            } else if (action == uint32(ISettlerActions.EKUBOV3_VIP.selector)) {
                 sellToEkuboV3VIP(recipient, feeOnTransfer, hashMul, hashMod, fills, permit, sig, amountOutMin);
+            } else { // if (action == uint32(ISettlerActions.PANCAKE_INFINITY_VIP.selector))
+                sellToPancakeInfinityVIP(recipient, feeOnTransfer, hashMul, hashMod, fills, permit, sig, amountOutMin);
             }
         } else {
             return false;

src/core/PancakeInfinity.sol

@@ -37,8 +37,6 @@ interface IPancakeInfinityVault {
     function lock(bytes calldata data) external returns (bytes memory);
 }
 
-IPancakeInfinityVault constant VAULT = IPancakeInfinityVault(0x238a358808379702088667322f80aC48bAd5e6c4);
-
 /// @notice Interface for the callback executed when an address locks the vault
 interface IPancakeInfinityLockCallback {
     /// @notice Called by the pool manager on `msg.sender` when a lock is acquired
@@ -92,9 +90,6 @@ interface IPancakeInfinityCLPoolManager is IPancakeInfinityPoolManager {
         returns (BalanceDelta delta);
 }
 
-IPancakeInfinityCLPoolManager constant CL_MANAGER =
-    IPancakeInfinityCLPoolManager(0xa0FfB9c1CE1Fe56963B0321B32E7A0302114058b);
-
 interface IPancakeInfinityBinPoolManager is IPancakeInfinityPoolManager {
     /// @notice Peform a swap to a pool
     /// @param key The pool key
@@ -194,10 +189,7 @@ library UnsafePancakeInfinityBinPoolManager {
     }
 }
 
-IPancakeInfinityBinPoolManager constant BIN_MANAGER =
-    IPancakeInfinityBinPoolManager(0xC697d2898e0D09264376196696c51D7aBbbAA4a9);
-
-abstract contract PancakeInfinity is SettlerSwapAbstract {
+abstract contract PancakeInfinityBase is SettlerSwapAbstract {
     using UnsafeMath for uint256;
     using UnsafeMath for int256;
     using Ternary for bool;
@@ -214,6 +206,8 @@ abstract contract PancakeInfinity is SettlerSwapAbstract {
         assert(address(ETH_ADDRESS) == NotesLib.ETH_ADDRESS);
     }
 
+    function _PANCAKE_INFINITY_VAULT() internal pure virtual returns (address vault);
+
     //// How to generate `fills` for Pancake Infinity:
     ////
     //// Linearize your DAG of fills by doing a topological sort on the tokens involved. In the
@@ -279,7 +273,10 @@ abstract contract PancakeInfinity is SettlerSwapAbstract {
             amountOutMin
         );
         bytes memory encodedBuyAmount = _setOperatorAndCall(
-            address(VAULT), data, uint32(IPancakeInfinityLockCallback.lockAcquired.selector), _pancakeInfinityCallback
+            _PANCAKE_INFINITY_VAULT(),
+            data,
+            uint32(IPancakeInfinityLockCallback.lockAcquired.selector),
+            _pancakeInfinityCallback
         );
         // buyAmount = abi.decode(abi.decode(encodedBuyAmount, (bytes)), (uint256));
         assembly ("memory-safe") {
@@ -313,7 +310,10 @@ abstract contract PancakeInfinity is SettlerSwapAbstract {
             amountOutMin
         );
         bytes memory encodedBuyAmount = _setOperatorAndCall(
-            address(VAULT), data, uint32(IPancakeInfinityLockCallback.lockAcquired.selector), _pancakeInfinityCallback
+            _PANCAKE_INFINITY_VAULT(),
+            data,
+            uint32(IPancakeInfinityLockCallback.lockAcquired.selector),
+            _pancakeInfinityCallback
         );
         // buyAmount = abi.decode(abi.decode(encodedBuyAmount, (bytes)), (uint256));
         assembly ("memory-safe") {
@@ -506,33 +506,13 @@ abstract contract PancakeInfinity is SettlerSwapAbstract {
 
                 Decoder.overflowCheck(data);
 
-                if (uint256(poolManagerId) == 0) {
-                    poolKey.poolManager = CL_MANAGER;
-
-                    _pancakeInfinitySettleDelta(
-                        state,
-                        IPancakeInfinityCLPoolManager(address(poolKey.poolManager))
-                            .unsafeSwap(poolKey, zeroForOne, amountSpecified, sqrtPriceLimitX96, hookData),
-                        zeroForOne
-                    );
-                } else if (uint256(poolManagerId) == 1) {
-                    poolKey.poolManager = BIN_MANAGER;
-                    if (amountSpecified >> 127 != amountSpecified >> 128) {
-                        Panic.panic(Panic.ARITHMETIC_OVERFLOW);
-                    }
-                    _pancakeInfinitySettleDelta(
-                        state,
-                        IPancakeInfinityBinPoolManager(address(poolKey.poolManager))
-                            .unsafeSwap(poolKey, zeroForOne, int128(amountSpecified), hookData),
-                        zeroForOne
-                    );
-                } else {
-                    assembly ("memory-safe") {
-                        mstore(0x00, 0x0a9a7da6) // selector for `UnknownPoolManagerId(uint8)`
-                        mstore(0x20, and(0xff, poolManagerId))
-                        revert(0x1c, 0x24)
-                    }
-                }
+                _pancakeInfinitySettleDelta(
+                    state,
+                    _dispatchPancakeInfinity(
+                        poolManagerId, poolKey, zeroForOne, amountSpecified, sqrtPriceLimitX96, hookData
+                    ),
+                    zeroForOne
+                );
             }
         }
 
@@ -593,4 +573,48 @@ abstract contract PancakeInfinity is SettlerSwapAbstract {
             return returndata;
         }
     }
+
+    // Each fork mixin in `pancakeInfinityForks/` defines its binding of pool manager IDs to pool
+    // managers by overriding this function with one that routes each recognized ID to
+    // `swapToClManager` or `swapToBinManager` with the appropriate pool manager's address, and
+    // calls `revertUnknownPoolManagerId` otherwise. A fork that lacks one of the pool manager
+    // types simply omits that route, which also omits the corresponding swap code from the
+    // compiled contract.
+    function _dispatchPancakeInfinity(
+        uint8 poolManagerId,
+        PoolKey memory poolKey,
+        bool zeroForOne,
+        int256 amountSpecified,
+        uint160 sqrtPriceLimitX96,
+        bytes calldata hookData
+    ) internal virtual returns (BalanceDelta);
+
+    function swapToClManager(
+        address clManager,
+        PoolKey memory poolKey,
+        bool zeroForOne,
+        int256 amountSpecified,
+        uint160 sqrtPriceLimitX96,
+        bytes calldata hookData
+    ) internal returns (BalanceDelta) {
+        poolKey.poolManager = IPancakeInfinityPoolManager(clManager);
+        return IPancakeInfinityCLPoolManager(clManager)
+            .unsafeSwap(poolKey, zeroForOne, amountSpecified, sqrtPriceLimitX96, hookData);
+    }
+
+    function swapToBinManager(
+        address binManager,
+        PoolKey memory poolKey,
+        bool zeroForOne,
+        int256 amountSpecified,
+        bytes calldata hookData
+    ) internal returns (BalanceDelta) {
+        poolKey.poolManager = IPancakeInfinityPoolManager(binManager);
+        if (amountSpecified >> 127 != amountSpecified >> 128) {
+            Panic.panic(Panic.ARITHMETIC_OVERFLOW);
+        }
+        return
+            IPancakeInfinityBinPoolManager(binManager)
+                .unsafeSwap(poolKey, zeroForOne, int128(amountSpecified), hookData);
+    }
 }

src/core/SettlerErrors.sol

@@ -116,6 +116,14 @@ error NotConverged();
 ///         the list of recognized pool managers.
 error UnknownPoolManagerId(uint8 poolManagerId);
 
+function revertUnknownPoolManagerId(uint8 poolManagerId) pure {
+    assembly ("memory-safe") {
+        mstore(0x00, 0x0a9a7da6) // selector for `UnknownPoolManagerId(uint8)`
+        mstore(0x20, and(0xff, poolManagerId))
+        revert(0x1c, 0x24)
+    }
+}
+
 /// @notice Thrown when the `msg.value` is less than the minimum expected value.
 error Underpayment(uint256 msgValueMin, uint256 msgValueActual);
 

src/core/pancakeInfinityForks/OrvexCL.sol

@@ -0,0 +1,30 @@
+// SPDX-License-Identifier: MIT
+pragma solidity ^0.8.25;
+
+import {PancakeInfinityBase, PoolKey} from "../PancakeInfinity.sol";
+import {BalanceDelta} from "../UniswapV4Types.sol";
+import {revertUnknownPoolManagerId} from "../SettlerErrors.sol";
+
+address constant orvexVault = 0xFe7E25dE55e5cBbEcCcb661F3679F873f72B9b0D;
+address constant orvexClManager = 0xd01C774d4A66408326Bc65728Ac5Ae5aAf004032;
+
+abstract contract OrvexCL is PancakeInfinityBase {
+    function _PANCAKE_INFINITY_VAULT() internal pure override returns (address) {
+        return orvexVault;
+    }
+
+    function _dispatchPancakeInfinity(
+        uint8 poolManagerId,
+        PoolKey memory poolKey,
+        bool zeroForOne,
+        int256 amountSpecified,
+        uint160 sqrtPriceLimitX96,
+        bytes calldata hookData
+    ) internal override returns (BalanceDelta) {
+        if (poolManagerId == 0) {
+            return swapToClManager(orvexClManager, poolKey, zeroForOne, amountSpecified, sqrtPriceLimitX96, hookData);
+        } else {
+            revertUnknownPoolManagerId(poolManagerId);
+        }
+    }
+}

src/core/pancakeInfinityForks/PancakeInfinity.sol

@@ -0,0 +1,35 @@
+// SPDX-License-Identifier: MIT
+pragma solidity ^0.8.25;
+
+import {PancakeInfinityBase, PoolKey} from "../PancakeInfinity.sol";
+import {BalanceDelta} from "../UniswapV4Types.sol";
+import {revertUnknownPoolManagerId} from "../SettlerErrors.sol";
+
+address constant pancakeInfinityVault = 0x238a358808379702088667322f80aC48bAd5e6c4;
+address constant pancakeInfinityClManager = 0xa0FfB9c1CE1Fe56963B0321B32E7A0302114058b;
+address constant pancakeInfinityBinManager = 0xC697d2898e0D09264376196696c51D7aBbbAA4a9;
+
+abstract contract PancakeInfinity is PancakeInfinityBase {
+    function _PANCAKE_INFINITY_VAULT() internal pure override returns (address) {
+        return pancakeInfinityVault;
+    }
+
+    function _dispatchPancakeInfinity(
+        uint8 poolManagerId,
+        PoolKey memory poolKey,
+        bool zeroForOne,
+        int256 amountSpecified,
+        uint160 sqrtPriceLimitX96,
+        bytes calldata hookData
+    ) internal override returns (BalanceDelta) {
+        if (poolManagerId == 0) {
+            return swapToClManager(
+                pancakeInfinityClManager, poolKey, zeroForOne, amountSpecified, sqrtPriceLimitX96, hookData
+            );
+        } else if (poolManagerId == 1) {
+            return swapToBinManager(pancakeInfinityBinManager, poolKey, zeroForOne, amountSpecified, hookData);
+        } else {
+            revertUnknownPoolManagerId(poolManagerId);
+        }
+    }
+}