Repository navigation
Expand file tree
/
Copy pathCMakeLists.txt
More file actions
239 lines (218 loc) · 9.58 KB
/
Copy pathCMakeLists.txt
File metadata and controls
239 lines (218 loc) · 9.58 KB
1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36
37
38
39
40
41
42
43
44
45
46
47
48
49
50
51
52
53
54
55
56
57
58
59
60
61
62
63
64
65
66
67
68
69
70
71
72
73
74
75
76
77
78
79
80
81
82
83
84
85
86
87
88
89
90
91
92
93
94
95
96
97
98
99
100
101
102
103
104
105
106
107
108
109
110
111
112
113
114
115
116
117
118
119
120
121
122
123
124
125
126
127
128
129
130
131
132
133
134
135
136
137
138
139
140
141
142
143
144
145
146
147
148
149
150
151
152
153
154
155
156
157
158
159
160
161
162
163
164
165
166
167
168
169
170
171
172
173
174
175
176
177
178
179
180
181
182
183
184
185
186
187
188
189
190
191
192
193
194
195
196
197
198
199
200
201
202
203
204
205
206
207
208
209
210
211
212
213
214
215
216
217
218
219
220
221
222
223
224
225
226
227
228
229
230
231
232
233
234
235
236
237
238
239
cmake_minimum_required(VERSION 3.22)
project(rdf4cpp VERSION 0.4.0)
set(POBR_VERSION 5) # Persisted Object Binary Representation
include(cmake/boilerplate_init.cmake)
boilerplate_init()
if (PROJECT_IS_TOP_LEVEL)
# Strip the dependencies down to what rdf4cpp uses. This has to be a profile, see conan/slim.profile.
set(CONAN_INSTALL_ARGS "${CONAN_INSTALL_ARGS};-pr:h=${CMAKE_CURRENT_SOURCE_DIR}/conan/slim.profile")
# b2 hands clang a made-up --target=arm64-pc-linux (tools/build/src/tools/clang.jam,
# init-flags-cross). Clang has no aarch64 candidate triple with the pc vendor, so on
# Debian/Ubuntu it finds no libstdc++ and every C++ file fails on <cstddef>.
# Appending the compiler's own triple wins: extra_b2_flags is passed after b2's own flags.
if (CMAKE_SYSTEM_NAME STREQUAL "Linux"
AND CMAKE_SYSTEM_PROCESSOR MATCHES "aarch64|arm64"
AND CMAKE_CXX_COMPILER_ID MATCHES "Clang")
execute_process(COMMAND "${CMAKE_CXX_COMPILER}" -print-target-triple OUTPUT_VARIABLE HOST_TRIPLE OUTPUT_STRIP_TRAILING_WHITESPACE)
set(CONAN_INSTALL_ARGS "${CONAN_INSTALL_ARGS};-o=boost/*:extra_b2_flags=cflags=--target=${HOST_TRIPLE} linkflags=--target=${HOST_TRIPLE}")
endif ()
if (BUILD_TESTING)
set(CONAN_INSTALL_ARGS "${CONAN_INSTALL_ARGS};-o=&:with_test_deps=True")
endif ()
endif ()
# find packages
find_package(Boost REQUIRED COMPONENTS charconv)
find_package(PCRE2 REQUIRED)
find_package(botan REQUIRED)
find_package(uni-algo REQUIRED)
find_package(highway REQUIRED)
find_package(dice-hash REQUIRED)
find_package(dice-sparse-map REQUIRED)
find_package(dice-template-library REQUIRED)
find_package(libxml2 REQUIRED)
find_package(simdjson REQUIRED)
find_package(dragonbox REQUIRED)
configure_file(${CMAKE_CURRENT_SOURCE_DIR}/cmake/version.hpp.in ${CMAKE_CURRENT_SOURCE_DIR}/src/rdf4cpp/version.hpp)
include(FetchContent)
# serd is compiled directly into rdf4cpp, we only need its sources.
# serd builds with meson and ships no CMakeLists.txt, so FetchContent_MakeAvailable
# only makes the sources available and adds no target of its own.
FetchContent_Declare(serd
GIT_REPOSITORY https://github.com/dice-group/serd.git
GIT_TAG 12321d54430b4e9caf30903eff0203a372c94fd0 # v0.32.10+dice
)
FetchContent_MakeAvailable(serd)
# keep serd's license at a stable path, it is picked up from there while packaging (see conanfile.py)
file(COPY "${serd_SOURCE_DIR}/COPYING" DESTINATION "${CMAKE_CURRENT_BINARY_DIR}/serd")
set(serd_source_files
src/base64.c
src/byte_source.c
src/env.c
src/n3.c
src/node.c
src/reader.c
src/read_utf8.c
src/string.c
src/system.c
src/uri.c
src/writer.c
)
list(TRANSFORM serd_source_files PREPEND "${serd_SOURCE_DIR}/")
set(style_files
.clang-format
.clang-tidy
)
foreach(style_file ${style_files})
file(DOWNLOAD "https://raw.githubusercontent.com/dice-group/tentris-cpp-coding-guidelines/main/${style_file}"
"${CMAKE_SOURCE_DIR}/${style_file}"
TLS_VERIFY ON)
endforeach()
## Create the main rdf4cpp library target
add_library(rdf4cpp
src/rdf4cpp/BlankNode.cpp
src/rdf4cpp/ClosedNamespace.cpp
src/rdf4cpp/CompensatedSum.cpp
src/rdf4cpp/Dataset.cpp
src/rdf4cpp/DeferredLiteral.cpp
src/rdf4cpp/Graph.cpp
src/rdf4cpp/IRI.cpp
src/rdf4cpp/Literal.cpp
src/rdf4cpp/Namespace.cpp
src/rdf4cpp/Node.cpp
src/rdf4cpp/Quad.cpp
src/rdf4cpp/Statement.cpp
src/rdf4cpp/bnode_mngt/reference_backends/generator/RandomIdGenerator.cpp
src/rdf4cpp/bnode_mngt/reference_backends/generator/IncreasingIdGenerator.cpp
src/rdf4cpp/datatypes/registry/DatatypeRegistry.cpp
src/rdf4cpp/datatypes/owl/Rational.cpp
src/rdf4cpp/datatypes/owl/Real.cpp
src/rdf4cpp/datatypes/rdf/LangString.cpp
src/rdf4cpp/datatypes/xsd/Base64Binary.cpp
src/rdf4cpp/datatypes/xsd/Boolean.cpp
src/rdf4cpp/datatypes/xsd/Decimal.cpp
src/rdf4cpp/datatypes/xsd/Double.cpp
src/rdf4cpp/datatypes/xsd/Float.cpp
src/rdf4cpp/datatypes/xsd/HexBinary.cpp
src/rdf4cpp/datatypes/xsd/String.cpp
src/rdf4cpp/datatypes/xsd/AnyURI.cpp
src/rdf4cpp/datatypes/xsd/integers/non_negative/NonNegativeInteger.cpp
src/rdf4cpp/datatypes/xsd/integers/non_negative/PositiveInteger.cpp
src/rdf4cpp/datatypes/xsd/integers/non_negative/UnsignedByte.cpp
src/rdf4cpp/datatypes/xsd/integers/non_negative/UnsignedInt.cpp
src/rdf4cpp/datatypes/xsd/integers/non_negative/UnsignedLong.cpp
src/rdf4cpp/datatypes/xsd/integers/non_negative/UnsignedShort.cpp
src/rdf4cpp/datatypes/xsd/integers/non_positive/NegativeInteger.cpp
src/rdf4cpp/datatypes/xsd/integers/non_positive/NonPositiveInteger.cpp
src/rdf4cpp/datatypes/xsd/integers/signed/Byte.cpp
src/rdf4cpp/datatypes/xsd/integers/signed/Int.cpp
src/rdf4cpp/datatypes/xsd/integers/signed/Integer.cpp
src/rdf4cpp/datatypes/xsd/integers/signed/Long.cpp
src/rdf4cpp/datatypes/xsd/integers/signed/Short.cpp
src/rdf4cpp/datatypes/xsd/time/Year.cpp
src/rdf4cpp/datatypes/xsd/time/Month.cpp
src/rdf4cpp/datatypes/xsd/time/Day.cpp
src/rdf4cpp/datatypes/xsd/time/YearMonth.cpp
src/rdf4cpp/datatypes/xsd/time/MonthDay.cpp
src/rdf4cpp/datatypes/xsd/time/Date.cpp
src/rdf4cpp/datatypes/xsd/time/Time.cpp
src/rdf4cpp/datatypes/xsd/time/DateTime.cpp
src/rdf4cpp/datatypes/xsd/time/DateTimeStamp.cpp
src/rdf4cpp/datatypes/xsd/time/Duration.cpp
src/rdf4cpp/datatypes/xsd/time/DayTimeDuration.cpp
src/rdf4cpp/datatypes/xsd/time/YearMonthDuration.cpp
src/rdf4cpp/namespaces/RDF.cpp
src/rdf4cpp/parser/IStreamQuadIterator.cpp
src/rdf4cpp/parser/RDFFileParser.cpp
src/rdf4cpp/query/QuadPattern.cpp
src/rdf4cpp/query/Solution.cpp
src/rdf4cpp/query/TriplePattern.cpp
src/rdf4cpp/query/Variable.cpp
src/rdf4cpp/regex/Regex.cpp
src/rdf4cpp/regex/RegexReplacer.cpp
src/rdf4cpp/util/CharMatcher.cpp
src/rdf4cpp/storage/NodeStorage.cpp
src/rdf4cpp/storage/reference_node_storage/SyncReferenceNodeStorage.cpp
src/rdf4cpp/storage/reference_node_storage/UnsyncReferenceNodeStorage.cpp
src/rdf4cpp/storage/view/BNodeBackendView.cpp
src/rdf4cpp/storage/view/IRIBackendView.cpp
src/rdf4cpp/storage/view/LiteralBackendView.cpp
src/rdf4cpp/storage/view/VariableBackendView.cpp
src/rdf4cpp/writer/SerializationState.cpp
src/rdf4cpp/IRIView.cpp
src/rdf4cpp/IRIFactory.cpp
src/rdf4cpp/util/Anonymizer.cpp
private/rdf4cpp/parser/IStreamQuadIteratorSerdImpl.cpp
private/rdf4cpp/parser/XMLParser.cpp
private/rdf4cpp/parser/XMLParserUtility.cpp
private/rdf4cpp/parser/XMLStates/XMLParserBaseState.cpp
private/rdf4cpp/parser/XMLStates/XMLParserCollectionState.cpp
private/rdf4cpp/parser/XMLStates/XMLParserDescriptionState.cpp
private/rdf4cpp/parser/XMLStates/XMLParserEmptyElement.cpp
private/rdf4cpp/parser/XMLStates/XMLParserInitialState.cpp
private/rdf4cpp/parser/XMLStates/XMLParserPredicateState.cpp
private/rdf4cpp/parser/XMLStates/XMLParserRDFState.cpp
private/rdf4cpp/parser/XMLStates/XMLParserTypedLiteralPredicateState.cpp
private/rdf4cpp/parser/XMLStates/XMLParserXMLLiteralState.cpp
private/rdf4cpp/parser/JsonLdParser.cpp
private/rdf4cpp/parser/JsonLdParserTypes.cpp
private/rdf4cpp/parser/JsonLdContextParser.cpp
private/rdf4cpp/parser/JsonLdExpandParser.cpp
private/rdf4cpp/regex/RegexImpl.cpp
private/rdf4cpp/regex/RegexReplacerImpl.cpp
${serd_source_files}
)
add_library(rdf4cpp::rdf4cpp ALIAS rdf4cpp)
target_include_directories(
rdf4cpp
PUBLIC
"$<BUILD_INTERFACE:${CMAKE_CURRENT_SOURCE_DIR}/src>"
PRIVATE
"$<BUILD_INTERFACE:${CMAKE_CURRENT_SOURCE_DIR}/private>"
"$<BUILD_INTERFACE:${serd_SOURCE_DIR}/include>"
"$<BUILD_INTERFACE:${serd_SOURCE_DIR}/src>"
)
target_link_libraries(rdf4cpp
PUBLIC
Boost::headers
Boost::charconv
dice-hash::dice-hash
dice-sparse-map::dice-sparse-map
dice-template-library::dice-template-library
PRIVATE
pcre2::pcre2
botan::botan
uni-algo::uni-algo
highway::highway
LibXml2::LibXml2
simdjson::simdjson
dragonbox::dragonbox
)
if (NOT MSVC)
# Highway's SIMD is extremely slow in Debug builds, so compile just that with optimizations.
set_source_files_properties(src/rdf4cpp/util/CharMatcher.cpp PROPERTIES
COMPILE_OPTIONS "$<$<CONFIG:Debug>:-O2>")
endif ()
set_target_properties(rdf4cpp PROPERTIES
VERSION ${PROJECT_VERSION}
SOVERSION ${PROJECT_VERSION_MAJOR}
CXX_STANDARD 23
CXX_EXTENSIONS OFF
CXX_STANDARD_REQUIRED ON
)
# consumers need C++23 as well, CXX_STANDARD alone does not propagate
target_compile_features(rdf4cpp PUBLIC cxx_std_23)
if (PROJECT_IS_TOP_LEVEL)
include(cmake/install_library.cmake)
install_cpp_library(rdf4cpp src)
endif ()
if (PROJECT_IS_TOP_LEVEL AND BUILD_TESTING)
message("Tests are configured to be build.")
include(CTest)
enable_testing()
add_subdirectory(tests)
endif ()
OPTION(BUILD_EXAMPLES "Build the examples for rdf4cpp." OFF)
if (PROJECT_IS_TOP_LEVEL AND BUILD_EXAMPLES)
message("Examples are configured to be build.")
add_subdirectory(examples)
endif ()