android-java-coverage-merger/build.gradle at master · ryansgot/android-java-coverage-merger · GitHub

1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36
37
38
39
40
41
42
43
44
45
46
47
48
49
50
51
52
53
54
55
56
57
58
59
60
61
62
63
64
65
66
67
68
69
70
71
72
73
74
75
76
77
78
79
80
81
82
83
84
85
86
87
88
89
90
91
92
93
94
95
96
97
98
99
100
101
102
103
104
105
106
107
108
109
110
111
112
113
114
115
116
117
118
119
120
121
122
123
124
125
126
127
128
129
130
131
132
133
134
apply plugin: 'groovy'
apply plugin: 'maven'
apply plugin: 'maven-publish'
apply plugin: 'signing'

group 'com.fsryan.gradle.coverage'
version '0.2.0'

repositories {
    mavenCentral()
}

dependencies {
    compile gradleApi()
    compile localGroovy()

    testCompile 'junit:junit:4.12'
}

java {
    targetCompatibility = JavaVersion.VERSION_1_8
    sourceCompatibility = JavaVersion.VERSION_1_8
}

task sourcesJar(type: Jar) {
    from sourceSets.main.groovy.srcDirs
    classifier = 'sources'
}

task javadocJar(type: Jar, dependsOn: javadoc) {
    classifier = 'javadoc'
    from javadoc.destinationDir
}

def siteUrl = 'https://github.com/ryansgot/android-java-coverage-merger'

publishing {
    repositories {
        maven {
            name 'releaseS3'
            url 's3://repo.fsryan.com/release'
            credentials(AwsCredentials) {
                accessKey = project.hasProperty("awsMavenAccessKey") ? project.property("awsMavenAccessKey") : "${System.env.AWS_ACCES_KEY_ID}"
                secretKey = project.hasProperty("awsMavenSecretKey") ? project.property("awsMavenSecretKey") : "${System.env.AWS_SECRET_KEY}"
            }
        }
        maven {
            name 'snapshotS3'
            url 's3://repo.fsryan.com/snapshot'
            credentials(AwsCredentials) {
                accessKey = project.hasProperty("awsMavenAccessKey") ? project.property("awsMavenAccessKey") : "${System.env.AWS_ACCES_KEY_ID}"
                secretKey = project.hasProperty("awsMavenSecretKey") ? project.property("awsMavenSecretKey") : "${System.env.AWS_SECRET_KEY}"
            }
        }
        maven {
            name = "releaseOSSRH"
            url 'https://s01.oss.sonatype.org/service/local/staging/deploy/maven2/'
            credentials {
                username =  project.findProperty("com.fsryan.ossrh.release.username") ?: ""
                password =  project.findProperty("com.fsryan.ossrh.release.password") ?: ""
            }
        }
        maven {
            name = "snapshotOSSRH"
            url 'https://s01.oss.sonatype.org/content/repositories/snapshots/'
            credentials {
                username =  project.findProperty("com.fsryan.ossrh.snapshot.username") ?: ""
                password =  project.findProperty("com.fsryan.ossrh.snapshot.password") ?: ""
            }
        }
    }
    publications {
        plugin(MavenPublication) {
            from components.java
            artifact sourcesJar
            artifact javadocJar
            groupId 'com.fsryan.gradle.coverage'
            artifactId 'android-java-coverage-merger'
            version project.version

            pom {
                licenses {
                    license {
                        name = "Mozilla Public License Version 2.0"
                        url = "https://www.mozilla.org/en-US/MPL/2.0/"
                        distribution = "repo"
                    }
                }
                developers {
                    developer {
                        id = 'fsryan'
                        name = 'Ryan Scott'
                        email = 'fsryan.developer@gmail.com'
                    }
                }
                scm {
                    connection = "${siteUrl}.git".toString()
                    developerConnection = "${siteUrl}.git".toString()
                    url = siteUrl
                }
                withXml {
                    def root = asNode()
                    root.appendNode('description', 'Gradle plugin providing tasks for generating combined android and java coverage reports')
                    root.appendNode('name', 'android-java-coverage-merger')
                    root.appendNode('url', 'https://github.com/ryansgot/android-java-coverage-merger')
                    root.children().last()
                }
            }
        }
    }
}

signing {

    if (project.hasProperty("signing.keyId")) {
        if (project.hasProperty("signing.password")) {
            if (project.hasProperty("signing.secretKeyRingFile")) {
                sign(publishing.publications)
            } else {
                println("Missing signing.secretKeyRingFile: cannot sign ${project.name}")
            }
        } else {
            println("Missing signing.password: cannot sign ${project.name}")
        }
    } else {
        println("Missing signing.keyId: cannot sign ${project.name}")
    }
}

afterEvaluate {
    def releaseTask = project.task("release", dependsOn: ["publishPluginPublicationToReleaseOSSRHRepository", "publishPluginPublicationToReleaseS3Repository"])
    releaseTask.description = "Release to OSSRH and S3"
    releaseTask.group = "Publishing"
}