dnf-ui/meson.build at main · dnfui/dnf-ui · GitHub

1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36
37
38
39
40
41
42
43
44
45
46
47
48
49
50
51
52
53
54
55
56
57
project(
  'dnf-ui',
  'cpp',
  version: '0.6.4',
  default_options: [
    'cpp_std=c++20',
    'warning_level=0',
    'werror=true',
  ],
)

add_project_arguments('-fdiagnostics-color=always', language: 'cpp')
add_project_arguments('-DDNFUI_VERSION="@0@"'.format(meson.project_version()), language: 'cpp')
add_project_arguments('-DGETTEXT_PACKAGE="@0@"'.format(meson.project_name()), language: 'cpp')
add_project_arguments(
  '-DLOCALEDIR="@0@"'.format(join_paths(get_option('prefix'), get_option('localedir'))),
  language: 'cpp',
)

if get_option('final_build')
  add_project_arguments(
    [
      '-DNDEBUG_BUILD',
      '-Wpedantic',
      '-Wmaybe-uninitialized',
      '-W',
      '-Wformat=2',
      '-Wpointer-arith',
      '-Wdisabled-optimization',
      '-Wfloat-equal',
    ],
    language: 'cpp',
  )
else
  add_project_arguments('-DDEBUG_BUILD', language: 'cpp')
endif

if get_option('debug_trace')
  add_project_arguments('-DDNFUI_DEBUG_TRACE', language: 'cpp')
endif

src_inc = include_directories('src')

libdnf5_dep = dependency('libdnf5')
gtk4_dep = dependency('gtk4')

desktop_file_dir = join_paths(get_option('datadir'), 'applications')
metainfo_dir = join_paths(get_option('datadir'), 'metainfo')
app_icon_root_dir = join_paths(get_option('datadir'), 'icons', 'hicolor')

subdir('src')
subdir('packaging')
subdir('po')

if get_option('build_tests')
  subdir('test')
endif